2011-08-18 如何取得使用者於系統中有幾份報表存在 ？(Retrieve Spool Information QSPSPLI API )

如何取得使用者於系統中有幾份報表存在 ？(Retrieve Spool Information QSPSPLI API )

File  : QRPGLESRC

Member: RTVSPLINFO

Type  : RPGLE

Usage : CRTBNDRPG RTVSPLINFO

OS    : V6R1

      * From V6R1 new Retrieve Spool Information (QSPSPLI) API
      * http://publib.boulder.ibm.com/infocenter/iseries/v6r1m0/index.jsp?topic=/apis/qspspli.htm
      *
      * PTF SI44375 for 6.1 and SI44376 for 7.1
      * Supersedes
      * PTF SI33959 for 6.1 and SI34013 for 7.1

     H DEBUG  OPTION(*SRCSTMT:*NODEBUGIO) DFTACTGRP(*NO) ACTGRP(*CALLER)

     DRtvSplInfo       pr                  extpgm('QSPSPLI')
     D RcvVar                     65535    options(*varsize)
     D RcvVarLen                     10I 0 const
     D Format                         8    const
     D ASP                           10    const
     D UsrName                       10    const
     D ErrCde                              likeds(ErrorCode)

     D SPLI0100        ds
     D   bytesRtn                    10I 0
     D   bytesAvl                    10I 0
     D   nbrOfSplFile                10I 0
     D   aspGrpName                  10A
     D   userName                    10A

     D ErrorCode       ds
     D   BytesProv                   10I 0 inz(%Size(ErrorCode))
     D   BytesAvail                  10I 0 inz(0)
     D   ExpMsgId                     7
     D   Reserved                     1
     D   ExptionData                256

      /free

       RtvSplInfo(SPLI0100        :
                  %size(SPLI0100) :
                  'SPLI0100'      :
                  '*SYSBAS'       :
                  '*CURRENT'      :
                  ErrorCode);

       dsply ('For ' + %trimr(aspGrpName) + ':');

       dsply (%trimr(userName) + ' has ' +
              %char(nbrOfSplFile) + ' spool files');

       RtvSplInfo(SPLI0100        :
                  %size(SPLI0100) :
                  'SPLI0100'      :
                  '*SYSBAS'       :
                  '*ALL'          :
                  ErrorCode);

       dsply ('All users have ' + %char(nbrOfSplFile) +
              ' spool files');

       *inlr = *on;

       return;

      /end-free



Retrieve Spool Information (QSPSPLI) API