2001-06-04 如何於ＣＬＰ中取得 AS/400 處理器屬於 IBM 哪一個 Group ?

如何於ＣＬＰ中取得 AS/400 處理器屬於 IBM 哪一個 Group ?

File  : QCLSRC
Member: RTVPRCGRPC
Type  : CLP

             PGM
             DCL        VAR(&RESULT) TYPE(*CHAR) LEN(64)
             DCL        VAR(&RSTLEN) TYPE(*CHAR) LEN(4)
             DCL        VAR(&FORMAT) TYPE(*CHAR) LEN(8) +
                          VALUE('PRDR0100')
             DCL        VAR(&OSINFO) TYPE(*CHAR) LEN(27) +
                          VALUE('*OPSYS *CUR  0000*CODE     ')
             DCL        VAR(&ERRCDE) TYPE(*CHAR) LEN(4)

             DCL        VAR(&RCVR) TYPE(*CHAR) LEN(64)
             DCL        VAR(&RCVRLEN) TYPE(*CHAR) LEN(4) +
                          VALUE(X'00000040')
             DCL        VAR(&RCVRFMT) TYPE(*CHAR) LEN(8) +
                          VALUE(LICR0200)
             DCL        VAR(&PRDID) TYPE(*CHAR) LEN(17) +
                          VALUE('             5050')
             DCL        VAR(&PRDFMT) TYPE(*CHAR) LEN(8) VALUE(LICP0100)
             DCL        VAR(&EC) TYPE(*CHAR) LEN(4) VALUE(X'00000000')
             DCL        VAR(&PRCGRP) TYPE(*CHAR) LEN(64)

             CHGVAR     VAR(%BIN(&RSTLEN 1 4)) VALUE(64)
             CHGVAR     VAR(%BIN(&ERRCDE 1 4)) VALUE(0)

             CALL       PGM(QSYS/QSZRTVPR) PARM(&RESULT &RSTLEN +
                               &FORMAT &OSINFO &ERRCDE)

             CHGVAR     VAR(%SST(&PRDID 1 13)) VALUE(%SST(&RESULT 13 +
                            13))

             CALL       PGM(QLZARTV) PARM(&RCVR &RCVRLEN &RCVRFMT +
                            &PRDID &PRDFMT &EC)
             CHGVAR     VAR(&PRCGRP) VALUE(%SST(&RCVR 48 3))

             SNDPGMMSG  MSG('Your Processer Group is ' *CAT +
                          &PRCGRP *TCAT '.') MSGTYPE(*COMP)

             ENDPGM



參考資料

1. IBM 使用上述程式所產生的 Processor Group 來訂定其系統程式收費等級。

2. 使用指令 WRKLICINF 亦可從結果畫面上得知 Processor Group.

3. AS/400e System Handbook http://www.redbooks.ibm.com/abstracts/ga195486.html

4. AS/400e System Builder http://www.redbooks.ibm.com/abstracts/sg242155.html